home *** CD-ROM | disk | FTP | other *** search
/ Die Speccy' 97 / Die Speccy' 97.iso / amiga_system / the_aminet / comm / mail / netmail_13.lha / NetMail / Drivers / Edge.reader < prev    next >
Text File  |  1995-08-12  |  2KB  |  86 lines
  1. /*
  2. ** $VER: Edge.reader 1.1 (11.8.95)
  3. ** Copyright (c) 1995 Riccardo Solmi
  4. **
  5. */
  6.  
  7. OPTIONS RESULTS
  8. OPTIONS FAILAT 21
  9.  
  10. cmd = 'Edge'
  11. IF ~EXISTS(cmd) THEN DO
  12.    cmd = GetVar('NetMail/EdgeCmd')
  13.    IF cmd = 0 | ~EXISTS(cmd) THEN DO
  14.       ADDRESS COMMAND 'SetEnv NetMail/EdgeCmd `Which "Edge"`'
  15.       cmd = GetVar('NetMail/EdgeCmd')
  16.       IF cmd = 0 THEN DO
  17.          ADDRESS COMMAND 'SetEnv NetMail/EdgeCmd `RequestFile Title "Select Edge command" Noicons`'
  18.          cmd = GetVar('NetMail/EdgeCmd')
  19.          IF cmd = 0 | ~EXISTS(cmd) THEN RETURN 2
  20.          ADDRESS COMMAND 'Copy QUIET ENV:NetMail/EdgeCmd ENVARC:NetMail/EdgeCmd'
  21.       END
  22.    END
  23. END
  24.  
  25. SELECT
  26.    WHEN UPPER(ARG(1)) = 'READ' THEN DO
  27.       PARSE ARG , file, port
  28.  
  29.       winpar  = ''
  30.       wininfo = GetVar('NetMail/ReaderWin')
  31.       IF wininfo ~= 0 THEN DO
  32.          PARSE VAR wininfo pL pT pW pH .
  33.          winpar = 'LEFTEDGE' pL 'TOPEDGE' pT 'WIDTH' pW 'HEIGHT' pH
  34.       END
  35.  
  36.       IF SHOW('P', 'EDGE') THEN DO
  37.          IF ~SHOW('P', port) | ~ABBREV(port, 'EDGE') THEN DO
  38.             ADDRESS 'EDGE'
  39.             'New' winpar
  40.             port = RESULT
  41.          END
  42.          ADDRESS VALUE port
  43.          'Open "'file'" FORCE'
  44.       END
  45.       ELSE DO
  46.          ADDRESS COMMAND
  47.          '"'cmd'" "'file'"'
  48.          'WaitForPort EDGE'
  49.          IF RC ~= 0 THEN RETURN 5
  50.          ADDRESS 'EDGE'
  51.          'AddressOf'
  52.          port = RESULT
  53.          ADDRESS VALUE port
  54.          IF winpar ~= '' THEN 'ChangeWindow' winpar
  55.       END
  56.       'Find "\010\010"'
  57.       'Position SOL'
  58.       'Cursor DOWN 2'
  59.       PARSE VAR RESULT line .
  60.       'MovePage UP' line
  61.    END
  62.    WHEN UPPER(ARG(1)) = 'CLEAR' THEN DO
  63.       PARSE ARG , port
  64.  
  65.       IF SHOW('P', port) & ABBREV(port, 'EDGE') THEN DO
  66.          ADDRESS VALUE port
  67.          'Clear FORCE'
  68.       END
  69.    END
  70.    WHEN UPPER(ARG(1)) = 'CLOSE' THEN DO
  71.       PARSE ARG , port
  72.  
  73.       IF SHOW('P', port) & ABBREV(port, 'EDGE') THEN DO
  74.          ADDRESS VALUE port
  75.          wininfo = GetVar('NetMail/ReaderWin')
  76.          PARSE VAR wininfo pL pT pW pH cLTWH
  77.          'Window'
  78.          PARSE VAR RESULT 'X 'pL', Y 'pT', W 'pW', H 'pH','
  79.          CALL SetVar('NetMail/ReaderWin', pL pT pW pH cLTWH)
  80.          'Flag _GE_Flags DormantQuit CLEAR'
  81.          'Close FORCE'
  82.       END
  83.    END
  84. END
  85. RETURN port
  86.